.key ""
.bra {
.ket }

; $VER: InstallDCF77 3.1 (2.4.99)

FailAt 100

Version >NIL:
IF NOT $Workbench GE "39."
	Echo "*nWorkbench 2.0/2.1 installation is running:*n"
	Echo "copying DCF77 and GClock to SYS:WBStartup...*n" 
	Resident >NIL: C:COPY PURE
	Resident >NIL: C:WAIT PURE
	Resident >NIL: C:ECHO PURE
	Resident >NIL: C:DELETE PURE

	/c/Retire DCF77
	Delete c:(DCF77|DCF77.info)
	Delete SYS:Utilities/(DCF77|DCF77.info)
	Delete SYS:Tools/Commodities/(DCF77|DCF77.info)

	CD "/Program"
	IF EXISTS DCF77
		Copy (DCF77|DCF77.info) SYS:WBStartup/
		CD /
		Copy Utilities/(GClock|GClock.info) SYS:WBStartup/
	Else
		Echo "*N Missing files.*n"
		Wait 5
		Endshell
	EndIf
	Echo "*nDCF77 installed.*n"
	Wait 5

Else

	RequestChoice >ENV:DCFSetup{$$} "InstallDCF77" "About to copy DCF77 to WBStartup*nand delete old versions of DCF77.*n" "Continue" "Cancel"
	IF $DCFSetup{$$} EQ "1"
		Resident >NIL: C:COPY PURE

		/c/Retire DCF77
		Delete c:(DCF77|DCF77.info)
		Delete SYS:Utilities/(DCF77|DCF77.info)
		Delete SYS:Tools/Commodities/(DCF77|DCF77.info)

		CD "/Program"
		IF EXISTS DCF77
			Copy (DCF77|DCF77.info) SYS:WBStartup/
			/c/FreeIconPosition SYS:WBStartup/DCF77
			CD /
			RequestChoice >ENV:DCFSetup{$$} "InstallDCF77" "Copy GClock to WBStartup?*n*n(GClock displays the receiver state.)*n" "Yes" "No"
			IF $DCFSetup{$$} EQ "1"
				Copy Utilities/(GClock|GClock.info) SYS:WBStartup/
				c/FreeIconPosition SYS:WBStartup/GClock
			EndIF
			RequestChoice >ENV:DCFSetup{$$} "InstallDCF77" "Copy TimeSignal to WBStartup?*n*n(TimeSignal plays a time signal.)*n" "Yes" "No"
			IF $DCFSetup{$$} EQ "1"
				Copy Utilities/TimeSignal SYS:WBStartup/
				IF NOT EXISTS SYS:WBStartup/TimeSignal.info
					Copy Utilities/TimeSignal.info SYS:WBStartup/
					c/FreeIconPosition SYS:WBStartup/TimeSignal
				EndIf
			EndIF
		Else
			Echo "*N Missing files.*n"
			Wait 5
			Endshell
		EndIf

		Delete ENV:DCFSetup{$$} QUIET

		RequestChoice >NIL: "InstallDCF77" "DCF77 is installed." "OK"
	Else
		Echo "*n Installation canceled."
	EndIF
EndIF

